TORQUES LABS

package {
  import flash.text.TextField;
  import flash.text.TextFieldAutoSize;
 
  public class AnimText extends TextField {
    private var _myParam:Number = 0;
 
    public function AnimText()
    {
      this.text = "DEFAULT";
      this.autoSize = TextFieldAutoSize.LEFT;
    }
 
    public function get myParam():Number {
      return _myParam;
    }
    public function set myParam(value:Number):void {
      _myParam = value;
      this.text = "PARAM[" + _myParam + "]";
      this.x    = _myParam;
    }
  }
}

var _animText:AnimText = new AnimText();
Tweener.addTween( _animText, { myParam:300, time:1 } );

// 登録コード.
// Tweener.addTween するまえに1度だけ呼び出して設定.
Tweener.registerSpecialProperty(
  "myParam",
  get_myParam,
  set_myParam
);
 
// 以下はsetter/getter関数.
public function get_myParam(
  p_obj:AnimText,
  param:Array,
  extra:Object = null ) :Number
{
  return p_obj.myParam;
}
public function set_myParam(
  p_obj:AnimText,
  value:Number,
  param:Array,
  extra:Object=null ) :void
{
  p_obj.myParam = value;
}

package {
  import caurina.transitions.Tweener;
  import flash.display.Sprite;
  import flash.events.Event;
 
  [SWF(backgroundColor="#aaaaaa", width="400", height="200")]
  public class Main extends Sprite {
    private var _animText:AnimText;
 
    // Tweenerでカスタムパラメータをtweenさせるデモ.
    public function Main():void {
      _animText = new AnimText();
      _animText.y = 100;
      addChild( _animText );
 
      Tweener.registerSpecialProperty(
        "myParam",
        get_myParam,
        set_myParam
      );
 
      // start animation yoyo.
      tweenFunc0();
    }
 
    // yoyo (go left)
    private function tweenFunc0() :void
    {
      Tweener.addTween( _animText,
        { myParam:0, time:1, onComplete:tweenFunc1 } );
    }
 
    // yoyo (go right)
    private function tweenFunc1() :void
    {
      Tweener.addTween( _animText,
        { myParam:300, time:1, onComplete:tweenFunc0 } );
    }
 
    // Tweenerで使用するためのアクセス関数.
    public function get_myParam(
      p_obj:AnimText,
      param:Array,
      extra:Object = null ) :Number
    {
      return p_obj.myParam;
    }
    public function set_myParam(
      p_obj:AnimText,
      value:Number,
      param:Array,
      extra:Object=null ) :void
    {
      p_obj.myParam = value;
    }
  }
}